project(danbooru_client)
cmake_minimum_required(VERSION 3.0 FATAL_ERROR)

set(danbooru_client_VERSION_MAJOR 0)
set(danbooru_client_VERSION_MINOR 3)
set(danbooru_client_VERSION_PATCH 0)

set (danbooru_VERSION ${danbooru_client_VERSION_MAJOR}.${danbooru_client_VERSION_MINOR}.${danbooru_client_VERSION_PATCH})

set(CPACK_PACKAGE_VERSION_MAJOR "${danbooru_client_VERSION_MAJOR}")
set(CPACK_PACKAGE_VERSION_MINOR "${danbooru_client_VERSION_MINOR}")
set(CPACK_PACKAGE_VERSION_PATCH "${danbooru_client_VERSION_PATCH}")
set(CPACK_SOURCE_GENERATOR "TXZ")
set(CPACK_SOURCE_PACKAGE_FILE_NAME
  "${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
set(CPACK_SOURCE_IGNORE_FILES
  "/build/;/.bzr/;~$;/.git/;${CPACK_SOURCE_IGNORE_FILES}")
include(CPack)

add_custom_target(dist COMMAND ${CMAKE_MAKE_PROGRAM} package_source)

find_package (ECM REQUIRED NO_MODULE)

set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${ECM_KDE_MODULE_DIR})

set(REQUIRED_QT_VERSION "5.4.0")
set(KF5_VERSION "5.7.0")

set(CMAKE_CXX_STANDARD 14)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

# Qt dependencies

find_package(Qt5 ${REQUIRED_QT_VERSION} NO_MODULE REQUIRED
             Core
             Widgets
             Quick
             QuickWidgets
             Test
             Qml)

# KF5 dependencies

find_package(KF5 ${KF5_VERSION} REQUIRED
             IconThemes         # Handling of icons
             CoreAddons         # Caches
             TextWidgets        # Spin boxes
             GuiAddons          # Image cache
             Config            # Configuration
             Completion         # KComboBox
             XmlGui             # User interface
             ConfigWidgets      # Handling of configuration
             KIO                # Jobs
             Wallet             # Password handling
             Declarative        # QML
             I18n               # i18n
             FileMetaData       # Tagging
             # DocTools           # Disabled until manual's ready
             )

include(ECMInstallIcons)
include(KDEInstallDirs)
include(KDECompilerSettings NO_POLICY_SCOPE)
include(KDECMakeSettings)
include(FeatureSummary)

set(CMAKE_INCLUDE_CURRENT_DIR ON)
set_package_properties(Qt5Test PROPERTIES TYPE OPTIONAL PURPOSE "Required to build tests")

# add_subdirectory( doc )
add_subdirectory( src )

feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)